Theory DefAss

(*  Title:       CoreC++
    ID:          $Id: DefAss.thy,v 1.6 2006-11-06 11:54:13 wasserra Exp $
    Author:      Tobias Nipkow, Daniel Wasserrab
    Maintainer:  Daniel Wasserrab <wasserra at fmi.uni-passau.de>
*)


header {* \isaheader{Definite assignment} *}

theory DefAss imports BigStep begin


section {*Hypersets*}

types hyperset = "vname set option"

constdefs
  hyperUn :: "hyperset => hyperset => hyperset"   (infixl "\<squnion>" 65)
  "A \<squnion> B  ≡  case A of None => None
                 | ⌊A⌋ => (case B of None => None | ⌊B⌋ => ⌊A ∪ B⌋)"

  hyperInt :: "hyperset => hyperset => hyperset"   (infixl "\<sqinter>" 70)
  "A \<sqinter> B  ≡  case A of None => B
                 | ⌊A⌋ => (case B of None => ⌊A⌋ | ⌊B⌋ => ⌊A ∩ B⌋)"

  hyperDiff1 :: "hyperset => vname => hyperset"   (infixl "\<ominus>" 65)
  "A \<ominus> a  ≡  case A of None => None | ⌊A⌋ => ⌊A - {a}⌋"

 hyper_isin :: "vname => hyperset => bool"   (infix "∈∈" 50)
"a ∈∈ A  ≡  case A of None => True | ⌊A⌋ => a ∈ A"

  hyper_subset :: "hyperset => hyperset => bool"   (infix "\<sqsubseteq>" 50)
  "A \<sqsubseteq> B  ≡  case B of None => True
                 | ⌊B⌋ => (case A of None => False | ⌊A⌋ => A ⊆ B)"

lemmas hyperset_defs =
 hyperUn_def hyperInt_def hyperDiff1_def hyper_isin_def hyper_subset_def

lemma [simp]: "⌊{}⌋ \<squnion> A = A  ∧  A \<squnion> ⌊{}⌋ = A"
by(simp add:hyperset_defs)

lemma [simp]: "⌊A⌋ \<squnion> ⌊B⌋ = ⌊A ∪ B⌋ ∧ ⌊A⌋ \<ominus> a = ⌊A - {a}⌋"
by(simp add:hyperset_defs)

lemma [simp]: "None \<squnion> A = None ∧ A \<squnion> None = None"
by(simp add:hyperset_defs)

lemma [simp]: "a ∈∈ None ∧ None \<ominus> a = None"
by(simp add:hyperset_defs)

lemma hyperUn_assoc: "(A \<squnion> B) \<squnion> C = A \<squnion> (B \<squnion> C)"
by(simp add:hyperset_defs Un_assoc)

lemma hyper_insert_comm: "A \<squnion> ⌊{a}⌋ = ⌊{a}⌋ \<squnion> A ∧ A \<squnion> (⌊{a}⌋ \<squnion> B) = ⌊{a}⌋ \<squnion> (A \<squnion> B)"
by(simp add:hyperset_defs)


section {*Definite assignment*}

consts
 \<A>  :: "expr => hyperset"
 \<A>s :: "expr list => hyperset"
 \<D>  :: "expr => hyperset => bool"
 \<D>s :: "expr list => hyperset => bool"

primrec
"\<A> (new C) = ⌊{}⌋"
"\<A> (Cast C e) = \<A> e"
"\<A> ((|C|)),e) = \<A> e"
"\<A> (Val v) = ⌊{}⌋"
"\<A> (e1 «bop» e2) = \<A> e1 \<squnion> \<A> e2"
"\<A> (Var V) = ⌊{}⌋"
"\<A> (LAss V e) = ⌊{V}⌋ \<squnion> \<A> e"
"\<A> (e•F{Cs}) = \<A> e"
"\<A> (e1•F{Cs}:=e2) = \<A> e1 \<squnion> \<A> e2"
"\<A> (Call e Copt M es) = \<A> e \<squnion> \<A>s es"
"\<A> ({V:T; e}) = \<A> e \<ominus> V"
"\<A> (e1;;e2) = \<A> e1 \<squnion> \<A> e2"
"\<A> (if (e) e1 else e2) =  \<A> e \<squnion> (\<A> e1 \<sqinter> \<A> e2)"
"\<A> (while (b) e) = \<A> b"
"\<A> (throw e) = None"

"\<A>s ([]) = ⌊{}⌋"
"\<A>s (e#es) = \<A> e \<squnion> \<A>s es"

primrec
"\<D> (new C) A = True"
"\<D> (Cast C e) A = \<D> e A"
"\<D> ((|C|)),e) A = \<D> e A"
"\<D> (Val v) A = True"
"\<D> (e1 «bop» e2) A = (\<D> e1 A ∧ \<D> e2 (A \<squnion> \<A> e1))"
"\<D> (Var V) A = (V ∈∈ A)"
"\<D> (LAss V e) A = \<D> e A"
"\<D> (e•F{Cs}) A = \<D> e A"
"\<D> (e1•F{Cs}:=e2) A = (\<D> e1 A ∧ \<D> e2 (A \<squnion> \<A> e1))"
"\<D> (Call e Copt M es) A = (\<D> e A ∧ \<D>s es (A \<squnion> \<A> e))"
"\<D> ({V:T; e}) A = \<D> e (A \<ominus> V)"
"\<D> (e1;;e2) A = (\<D> e1 A ∧ \<D> e2 (A \<squnion> \<A> e1))"
"\<D> (if (e) e1 else e2) A =
  (\<D> e A ∧ \<D> e1 (A \<squnion> \<A> e) ∧ \<D> e2 (A \<squnion> \<A> e))"
"\<D> (while (e) c) A = (\<D> e A ∧ \<D> c (A \<squnion> \<A> e))"
"\<D> (throw e) A = \<D> e A"

"\<D>s ([]) A = True"
"\<D>s (e#es) A = (\<D> e A ∧ \<D>s es (A \<squnion> \<A> e))"

lemma As_map_Val[simp]: "\<A>s (map Val vs) = ⌊{}⌋"
by (induct vs) simp_all

lemma D_append[iff]: "!!A. \<D>s (es @ es') A = (\<D>s es A ∧ \<D>s es' (A \<squnion> \<A>s es))"
by (induct es type:list) (auto simp:hyperUn_assoc)


lemma A_fv: "!!A. \<A> e = ⌊A⌋ ==> A ⊆ fv e"
and  "!!A. \<A>s es = ⌊A⌋ ==> A ⊆ fvs es"

apply(induct e and es)
apply (simp_all add:hyperset_defs)
apply blast+
done



lemma sqUn_lem: "A \<sqsubseteq> A' ==> A \<squnion> B \<sqsubseteq> A' \<squnion> B"
by(simp add:hyperset_defs) blast

lemma diff_lem: "A \<sqsubseteq> A' ==> A \<ominus> b \<sqsubseteq> A' \<ominus> b"
by(simp add:hyperset_defs) blast

(* This order of the premises avoids looping of the simplifier *)
lemma D_mono: "!!A A'. A \<sqsubseteq> A' ==> \<D> e A ==> \<D> (e::expr) A'"
and Ds_mono: "!!A A'. A \<sqsubseteq> A' ==> \<D>s es A ==> \<D>s (es::expr list) A'"

apply(induct e and es)
apply simp
apply simp
apply simp
apply simp
apply simp apply (iprover dest:sqUn_lem)
apply (fastsimp simp add:hyperset_defs)
apply simp
apply simp
apply simp apply (iprover dest:sqUn_lem)
apply simp apply (iprover dest:sqUn_lem)
apply simp apply (iprover dest:diff_lem)
apply simp apply (iprover dest:sqUn_lem)
apply simp apply (iprover dest:sqUn_lem)
apply simp apply (iprover dest:sqUn_lem)
apply simp
apply simp 
apply simp
apply (iprover dest:sqUn_lem)
done


(* And this is the order of premises preferred during application: *)
lemma D_mono': "\<D> e A ==> A \<sqsubseteq> A' ==> \<D> e A'"
and Ds_mono': "\<D>s es A ==> A \<sqsubseteq> A' ==> \<D>s es A'"
by(blast intro:D_mono, blast intro:Ds_mono)





end